(2CI)求两圆交点

;;说明:求两圆交点
;;参数:cen1:圆心1
;;参数:r1:半径1
;;参数:cen2:圆心2
;;参数:r2:半径2
;;返回:有交点侧返回交点列表，没有则返回nil
(defun 2ci(cen1 r1 cen2 r2 / a1 a2 a3 b2 b3 c3 cx1 cx2 cy1 cy2 delta x1 x12 x2 y1 y12 y2)
  (setq cx1 (car cen1) cy1 (cadr cen1) cx2 (car cen2) cy2 (cadr cen2))
    (cond
        ((and (= cx1 cx2) (/= cy1 cy2))
            (setq y12 (/ (+ (- (* r1 r1) (* r2 r2)) (- (* cy2 cy2) (* cy1 cy1))) 2.0 (- cy2 cy1)))
            (setq a3 1 b3 (* -2 cx1) c3 (+ (* (- y12 cy1) (- y12 cy1)) (* cx1 cx1) (* -1.0 r1 r1)))
            (setq delta (- (* b3 b3) (* 4.0 a3 c3)))
            (cond 
                ((> delta 0)
                    (setq x1 (/ (+ (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3))) 
                    (setq x2 (/ (- (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3)))
                    (list (list x1 y12) (list x2 y12))
                )
                ((= delta 0) (list (list (/ (* -1.0 b3) (* 2.0 a3)) y12)))
                (t (princ "\n没有交点！") nil)
            )
        )
        ((and (/= cx1 cx2) (= cy1 cy2))
            (setq x12 (/ (+ (- (* r1 r1) (* r2 r2)) (- (* cx2 cx2) (* cx1 cx1))) 2.0 (- cx2 cx1)))
            (setq a3 1 b3 (* -2 cy1) c3 (+ (* (- x12 cx1) (- x12 cx1)) (* cy1 cy1) (* -1.0 r1 r1)))
            (setq delta (- (* b3 b3) (* 4.0 a3 c3)))
            (cond 
                ((> delta 0)
                    (setq y1 (/ (+ (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3))) 
                    (setq y2 (/ (- (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3)))
                    (list (list x12 y1) (list x12 y2))
                )
                ((= delta 0) (list (list x12 (/ (* -1.0 b3) (* 2.0 a3)))))
                (t (princ "\n没有交点！") nil)
            )
        )
        ((and (= cx1 cx2) (= cy1 cy2))
            (cond
                ((= r1 r2) (alert "\n同一个圆求交点，怕不是个傻子吧你！"))
                (t (alert "\n同心圆求交点，你没毛病吧！"))
            )
            nil
        )
        (t
            (setq a1 (+ (- (* r1 r1) (* r2 r2)) (- (* cx2 cx2) (* cx1 cx1)) (- (* cy2 cy2) (* cy1 cy1))))
            (setq a2 (/ a1 2.0 (- cy2 cy1)))
            (setq b2 (/ (* 1.0 (- cx2 cx1)) (- cy2 cy1)))
            (setq a3 (+ 1.0 (* b2 b2)))
            (setq b3 (* -1 (+ (* 2.0 cx1) (* 2.0 (- a2 cy1) b2))))
            (setq c3 (- (+ (* cx1 cx1) (* (- a2 cy1) (- a2 cy1))) (* r1 r1)))
            (setq delta (- (* b3 b3) (* 4.0 a3 c3)))
            (cond 
                ((> delta 0)
                    (setq x1 (/ (+ (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3))) 
                    (setq x2 (/ (- (* -1.0 b3) (sqrt (- (* b3 b3) (* 4.0 a3 c3)))) (* 2.0 a3)))
                    (setq y1 (- a2 (* b2 x1)))
                    (setq y2 (- a2 (* b2 x2)))
                    (list (list x1 y1) (list x2 y2))
                )
                ((= delta 0) (list (list (setq x1 (/ (* -1.0 b3) (* 2.0 a3))) (- a2 (* b2 x1)))))
                (t (princ "\n没有交点！") nil)
            )
        )
    )
)
(2ci (list 100.0 100.0) 50 (list 120.0 30.0) 70.0)
((149.569 93.4483) (61.3745 68.2499))