7.9 组织Fortran项目

NOTE:此示例代码可以在 https://github.com/dev-cafe/cmake-cookbook/tree/v1.0/chapter-7/recipe-09 中找到，其中有一个Fortran示例。该示例在CMake 3.5版(或更高版本)中是有效的，并且已经在GNU/Linux、macOS和Windows上进行过测试。

我们来讨论如何构造和组织Fortran项目，原因有二:

  1. 现在，仍然有很多Fortran项目，特别是在数字软件中(有关通用Fortran软件项目的更全面列表，请参见http://fortranwiki.org/fortran/show/Libraries )。
  2. 对于不使用CMake的项目，Fortran 90(以及更高版本)可能更难构建，因为Fortran模块强制执行编译顺序。换句话说，对于手工编写的Makefile，通常需要为Fortran模块文件编写依赖扫描程序。

正如我们在本示例中所示，现代CMake允许我们以非常紧凑和模块化的方式配置和构建项目。作为一个例子，我们将使用前两个示例中的基本元胞自动机，现在将其移植到Fortran。

准备工作

文件树结构与前两个示例非常相似。我们用Fortran源代码替换了C++，现在就没有头文件了:

  1. .
  2. ├── CMakeLists.txt
  3. ├── external
  4. │    ├── CMakeLists.txt
  5. │    ├── conversion.f90
  6. │    └── README.md
  7. ├── src
  8. │    ├── CMakeLists.txt
  9. │    ├── evolution
  10. │    │    ├── ancestors.f90
  11. │    │    ├── CMakeLists.txt
  12. │    │    ├── empty.f90
  13. │    │    └── evolution.f90
  14. │    ├── initial
  15. │    │    ├── CMakeLists.txt
  16. │    │    └── initial.f90
  17. │    ├── io
  18. │    │    ├── CMakeLists.txt
  19. │    │    └── io.f90
  20. │    ├── main.f90
  21. │    └── parser
  22. │        ├── CMakeLists.txt
  23. │        └── parser.f90
  24. └── tests
  25.     ├── CMakeLists.txt
  26.     └── test.f90

主程序在src/main.f90中:

  1. program example
  3.   use parser, only: get_arg_as_int
  4.   use conversion, only: binary_representation
  5.   use initial, only: initial_distribution
  6.   use io, only: print_row
  7.   use evolution, only: evolve
  9.   implicit none
  11.   integer :: num_steps
  12.   integer :: length
  13.   integer :: rule_decimal
  14.   integer :: rule_binary(8)
  15.   integer, allocatable :: row(:)
  16.   integer :: step
  18.   ! parse arguments
  19.   num_steps = get_arg_as_int(1)
  20.   length = get_arg_as_int(2)
  21.   rule_decimal = get_arg_as_int(3)
  23.   ! print information about parameters
  24.   print *, "number of steps: ", num_steps
  25.   print *, "length: ", length
  26.   print *, "rule: ", rule_decimal
  28.   ! obtain binary representation for the rule
  29.   rule_binary = binary_representation(rule_decimal)
  31.   ! create initial distribution
  32.   allocate(row(length))
  33.   call initial_distribution(row)
  35.   ! print initial configuration
  36.   call print_row(row)
  38.   ! the system evolves, print each step
  39.   do step = 1, num_steps
  40.     call evolve(row, rule_binary)
  41.     call print_row(row)
  42.   end do
  44.   deallocate(row)
  45. end program

与前面的示例一样，我们已经将conversion模块放入external/conversion.f90中：

  1. module conversion
  3.   implicit none
  4.   public binary_representation
  5.   private
  7. contains
  9.   pure function binary_representation(n_decimal)
  10.     integer, intent(in) :: n_decimal
  11.     integer :: binary_representation(8)
  12.     integer :: pos
  13.     integer :: n
  15.     binary_representation = 0
  16.     pos = 8
  17.     n = n_decimal
  18.     do while (n > 0)
  19.       binary_representation(pos) = mod(n, 2)
  20.       n = (n - binary_representation(pos))/2
  21.       pos = pos - 1
  22.     end do
  23.   end function
  25. end module

evolution库分成三个文件，大部分在src/evolution/evolution.f90中:

  1. module evolution
  3.   implicit none
  4.   public evolve
  5.   private
  7. contains
  9.   subroutine not_visible()
  10.     ! no-op call to demonstrate private/public visibility
  11.     call empty_subroutine_no_interface()
  12.   end subroutine
  14.   pure subroutine evolve(row, rule_binary)
  15.     use ancestors, only: compute_ancestors
  17.     integer, intent(inout) :: row(:)
  18.     integer, intent(in) :: rule_binary(8)
  19.     integer :: i
  20.     integer :: left, center, right
  21.     integer :: ancestry
  22.     integer, allocatable :: new_row(:)
  24.     allocate(new_row(size(row)))
  26.     do i = 1, size(row)
  27.       left = i - 1
  28.       center = i
  29.       right = i + 1
  31.       if (left < 1) left = left + size(row)
  32.       if (right > size(row)) right = right - size(row)
  34.       ancestry = compute_ancestors(row, left, center, right)
  35.       new_row(i) = rule_binary(ancestry)
  36.     end do
  38.     row = new_row
  39.     deallocate(new_row)
  41.   end subroutine
  43. end module

祖先计算是在src/evolution/ancestors.f90：

  1. module ancestors
  3.   implicit none
  4.   public compute_ancestors
  5.   private
  7.   contains
  8.   pure integer function compute_ancestors(row, left, center, right) result(i)
  9.     integer, intent(in) :: row(:)
  10.     integer, intent(in) :: left, center, right
  12.     i = 4*row(left) + 2*row(center) + 1*row(right)
  13.     i = 8 - i
  14.   end function
  15. end module

还有一个“空”模块在src/evolution/empty.f90中：

  1. module empty
  3.   implicit none
  4.   public empty_subroutine
  5.   private
  7. contains
  9.   subroutine empty_subroutine()
  10.   end subroutine
  12. end module
  14. subroutine 
  15. empty_subroutine_no_interface()
  16.   use empty, only: empty_subroutine
  17.   call empty_subroutine()
  18. end subroutine

启动条件的代码位于src/initial/initial.f90：

  1. module initial
  3.   implicit none
  4.   public initial_distribution
  5.   private
  7. contains
  9.     pure subroutine initial_distribution(row)
  10.     integer, intent(out) :: row(:)
  12.     row = 0
  13.     row(size(row)/2) = 1
  14.     end subroutine
  16. end module

src/io/io.f90包含一个打印输出：

  1. module io
  3.   implicit none
  4.   public print_row
  5.   private
  7.   contains
  9.   subroutine print_row(row)
  10.     integer, intent(in) :: row(:)
  11.     character(size(row)) :: line
  12.     integer :: i
  14.     do i = 1, size(row)
  15.       if (row(i) == 1) then
  16.           line(i:i) = '*'
  17.       else
  18.           line(i:i) = ' '
  19.       end if
  20.     end do
  22.     print *, line
  23.   end subroutine
  25. end module

src/parser/parser.f90用于解析命令行参数：

  1. module parser
  3.   implicit none
  4.   public get_arg_as_int
  5.   private
  7.   contains
  9.   integer function get_arg_as_int(n) result(i)
  10.     integer, intent(in) :: n
  11.     character(len=32) :: arg
  13.     call get_command_argument(n, arg)
  14.     read(arg , *) i
  15.   end function
  16. end module

最后，使用tests/test.f90对上面的实现进行测试：

  1. program test
  3.   use evolution, only: evolve
  5.   implicit none
  7.   integer :: row(9)
  8.   integer :: expected_result(9)
  9.   integer :: rule_binary(8)
  10.   integer :: i
  12.   ! test rule 90
  13.   row = (/0, 1, 0, 1, 0, 1, 0, 1, 0/)
  14.   rule_binary = (/0, 1, 0, 1, 1, 0, 1, 0/)
  15.   call evolve(row, rule_binary)
  16.   expected_result = (/1, 0, 0, 0, 0, 0, 0, 0, 1/)
  17.   do i = 1, 9
  18.       if (row(i) /= expected_result(i)) then
  19.           print *, 'ERROR: test for rule 90 failed'
  20.           call exit(1)
  21.       end if
  22.   end do
  24.   ! test rule 222
  25.   row = (/0, 0, 0, 0, 1, 0, 0, 0, 0/)
  26.   rule_binary = (/1, 1, 0, 1, 1, 1, 1, 0/)
  27.   call evolve(row, rule_binary)
  28.   expected_result = (/0, 0, 0, 1, 1, 1, 0, 0, 0/)
  29.   do i = 1, 9
  30.       if (row(i) /= expected_result(i)) then
  31.           print *, 'ERROR: test for rule 222 failed'
  32.           call exit(1)
  33.       end if
  34.   end do
  35. end program

具体实施

  1. 主CMakeLists.txt类似于第7节，我们只是将CXX换成Fortran，去掉C++11的要求:

    1. cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
    3. project(recipe-09 LANGUAGES Fortran)
    5. include(GNUInstallDirs)
    6. set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY
    7. ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
    8. set(CMAKE_LIBRARY_OUTPUT_DIRECTORY
    9. ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
    10. set(CMAKE_RUNTIME_OUTPUT_DIRECTORY
    11. ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR})
    13. # defines targets and sources
    14. add_subdirectory(src)
    16. # contains an "external" library we will link to
    17. add_subdirectory(external)
    19. # enable testing and define tests
    20. enable_testing()
    21. add_subdirectory(tests)

  2. 目标和源在src/CMakeLists.txt中定义(conversion目标除外):

    1. add_executable(automata main.f90)
    3. add_subdirectory(evolution)
    4. add_subdirectory(initial)
    5. add_subdirectory(io)
    6. add_subdirectory(parser)
    8. target_link_libraries(automata
    9.   PRIVATE
    10.     conversion
    11.     evolution
    12.     initial
    13.     io
    14.     parser
    15.   )

  3. conversion库在external/CMakeLists.txt中定义:

    1. add_library(conversion "")
    3. target_sources(conversion
    4.   PUBLIC
    5.       ${CMAKE_CURRENT_LIST_DIR}/conversion.f90
    6.   )

  4. src/CMakeLists.txt文件添加了更多的子目录，这些子目录又包含CMakeLists.txt文件。它们在结构上都是相似的，例如：src/initial/CMakeLists.txt包含以下内容:

    1. add_library(initial "")
    3. target_sources(initial
    4.   PUBLIC
    5.       ${CMAKE_CURRENT_LIST_DIR}/initial.f90
    6.   )

  5. 有个例外的是src/evolution/CMakeLists.txt中的evolution库，我们将其分为三个源文件:

    1. add_library(evolution "")
    3. target_sources(evolution
    4.   PRIVATE
    5.       empty.f90
    6.   PUBLIC
    7.       ${CMAKE_CURRENT_LIST_DIR}/ancestors.f90
    8.       ${CMAKE_CURRENT_LIST_DIR}/evolution.f90
    9.   )

  6. 单元测试在tests/CMakeLists.txt中注册:

    1. add_executable(fortran_test test.f90)
    3. target_link_libraries(fortran_test evolution)
    5. add_test(
    6.   NAME
    7.       test_evolution
    8.   COMMAND
    9.       $<TARGET_FILE:fortran_test>
    10.   )

  7. 配置和构建项目，将产生以下输出:

    1. $ mkdir -p build
    2. $ cd build
    3. $ cmake ..
    4. $ cmake --build .
    5. Scanning dependencies of target conversion
    6. [ 4%] Building Fortran object external/CMakeFiles/conversion.dir/conversion.f90.o
    7. [ 8%] Linking Fortran static library ../lib64/libconversion.a
    8. [ 8%] Built target conversion
    9. Scanning dependencies of target evolution
    10. [ 12%] Building Fortran object src/evolution/CMakeFiles/evolution.dir/ancestors.f90.o
    11. [ 16%] Building Fortran object src/evolution/CMakeFiles/evolution.dir/empty.f90.o
    12. [ 20%] Building Fortran object src/evolution/CMakeFiles/evolution.dir/evolution.f90.o
    13. [ 25%] Linking Fortran static library ../../lib64/libevolution.a
    14. [ 25%] Built target evolution
    15. Scanning dependencies of target initial
    16. [ 29%] Building Fortran object src/initial/CMakeFiles/initial.dir/initial.f90.o
    17. [ 33%] Linking Fortran static library ../../lib64/libinitial.a
    18. [ 33%] Built target initial
    19. Scanning dependencies of target io
    20. [ 37%] Building Fortran object src/io/CMakeFiles/io.dir/io.f90.o
    21. [ 41%] Linking Fortran static library ../../lib64/libio.a
    22. [ 41%] Built target io
    23. Scanning dependencies of target parser
    24. [ 45%] Building Fortran object src/parser/CMakeFiles/parser.dir/parser.f90.o
    25. [ 50%] Linking Fortran static library ../../lib64/libparser.a
    26. [ 50%] Built target parser
    27. Scanning dependencies of target example
    28. [ 54%] Building Fortran object src/CMakeFiles/example.dir/__/external/conversion.f90.o
    29. [ 58%] Building Fortran object src/CMakeFiles/example.dir/evolution/ancestors.f90.o
    30. [ 62%] Building Fortran object src/CMakeFiles/example.dir/evolution/evolution.f90.o
    31. [ 66%] Building Fortran object src/CMakeFiles/example.dir/initial/initial.f90.o
    32. [ 70%] Building Fortran object src/CMakeFiles/example.dir/io/io.f90.o
    33. [ 75%] Building Fortran object src/CMakeFiles/example.dir/parser/parser.f90.o
    34. [ 79%] Building Fortran object src/CMakeFiles/example.dir/main.f90.o
    35. [ 83%] Linking Fortran executable ../bin/example
    36. [ 83%] Built target example
    37. Scanning dependencies of target fortran_test
    38. [ 87%] Building Fortran object tests/CMakeFiles/fortran_test.dir/__/src/evolution/ancestors.f90.o
    39. [ 91%] Building Fortran object tests/CMakeFiles/fortran_test.dir/__/src/evolution/evolution.f90.o
    40. [ 95%] Building Fortran object tests/CMakeFiles/fortran_test.dir/test.f90.o
    41. [100%] Linking Fortran executable

  8. 最后，运行单元测试：

    1. $ ctest
    3. Running tests...
    4. Start 1: test_evolution
    5. 1/1 Test #1: test_evolution ................... Passed 0.00 sec
    7. 100% tests passed, 0 tests failed out of 1

工作原理

第7节中使用add_subdirectory限制范围，将从下往上讨论CMake结构，从定义每个库的单个CMakeLists.txt文件开始，比如src/evolution/CMakeLists.txt:

  1. add_library(evolution "")
  2. target_sources(evolution
  3.   PRIVATE
  4.       empty.f90
  5.   PUBLIC
  6.     ${CMAKE_CURRENT_LIST_DIR}/ancestors.f90
  7.     ${CMAKE_CURRENT_LIST_DIR}/evolution.f90
  8.   )

这些独立的CMakeLists.txt文件定义了源文件的库，遵循与前两个示例相同的方式：开发或维护人员可以对其中文件分而治之。

首先用add_library定义库名，然后定义它的源和包含目录，以及它们的目标可见性。这种情况下，因为它们的模块接口是在库之外访问，所以ancestors.f90和evolution.f90都是PUBLIC，而模块接口empty.f90不能在文件之外访问，因此将其标记为PRIVATE。

向上移动一层，库在src/CMakeLists.txt中封装：

  1. add_executable(automata main.f90)
  3. add_subdirectory(evolution)
  4. add_subdirectory(initial)
  5. add_subdirectory(io)
  6. add_subdirectory(parser)
  8. target_link_libraries(automata
  9.   PRIVATE
  10.     conversion
  11.     evolution
  12.     initial
  13.     io
  14.     parser
  15.   )

这个文件在主CMakeLists.txt中被引用。这意味着我们使用CMakeLists.txt文件(使用add_subdirectory添加)构建项目。正如第7节中讨论的，使用add_subdirectory限制范围，这种方法可以扩展到更大型的项目，而不需要在多个目录之间的全局变量中携带源文件列表，还可以隔离范围和名称空间。

将这个Fortran示例与C++版本(第7节)进行比较，我们可以注意到，在Fortran的情况下，相对的CMake工作量比较小；我们不需要使用target_include_directory，因为没有头文件，接口是通过生成的Fortran模块文件进行通信。另外，我们既不需要担心target_sources中列出的源文件的顺序，也不需要在库之间强制执行任何显式依赖关系。CMake能够从源文件依赖项推断Fortran模块依赖项。使用target_sources与PRIVATE和PUBLIC资源结合使用，以紧凑和健壮的方式表示接口。

更多信息

这个示例中，我们没有指定应该放置Fortran模块文件的目录，并且保持了这个透明。模块文件的位置可以通过设置CMAKE_Fortran_MODULE_DIRECTORY变量来指定。注意，也可以将其设置为Fortran_MODULE_DIRECTORY，从而实现更好的控制。详细可见：https://cmake.org/cmake/help/v3.5/prop_tgt/Fortran_MODULE_DIRECTORY.html