15.1 如何开始迁移项目

我们将首先说明，在哪里可以找到我们的示例，然后对移植，进行逐步的讨论。

复制要移植的示例

我们将从Vim源代码库的v8.1.0290发行标记开始(https://github.com/vim/vim) ，我们的工作基于Git提交哈希值b476cb7进行。 通过克隆Vim的源代码库并检出特定版本的代码，可以复制以下步骤:

  1. $ git clone --single-branch -b v8.1.0290 https://github.com/vim/vim.git

或者，我们的解决方案可以在cmake-support分支上找到，网址是 https://github.com/dev-cafe/vim ，并使用以下方法克隆下来:

  1. $ git clone --single-branch -b cmake-support https://github.com/dev-cafe/vim

在本例中，我们将使用CMake模拟./configure --enable-gui=no的配置方式。

为了与后面的解决方案进行比较，建议读者也可以研究以下Neovim项目(https://github.com/neovim/neovim )，这是传统Vi编辑器的一个分支，提供了一个CMake构建系统。

创建一个主CMakeLists.txt

首先，我们在源代码存储库的根目录中创建主CMakeLists.txt，在这里我们设置了最低CMake版本、项目名称和支持的语言，在本例中是C：

  1. cmake_minimum_required(VERSION
  2. 3.5 FATAL_ERROR)
  3. project(vim LANGUAGES C)

添加任何目标或源之前，可以设置默认的构建类型。本例中，我们默认为Release配置，这将打开某些编译器优化选项:

  1. if(NOT CMAKE_BUILD_TYPE)
  2.     set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type" FORCE)
  3. endif()

我们也使用可移植的安装目录变量：

  1. include(GNUInstallDirs)
  2. set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY
  3.     ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
  4. set(CMAKE_LIBRARY_OUTPUT_DIRECTORY
  5.     ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR})
  6. set(CMAKE_RUNTIME_OUTPUT_DIRECTORY
  7.     ${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR})

作为一个完整性检查，我们可以尝试配置和构建项目，但到目前为止还没有目标，所以构建步骤的输出是空的:

  1. $ mkdir -p build
  2. $ cd build
  3. $ cmake ..
  4. $ cmake --build .

我们一会儿就要开始添加目标了。

如何让常规和CMake配置共存

CMake的一个特性是在源代码之外构建，构建目录可以是任何目录，而不必是项目目录的子目录。这意味着，我们可以将一个项目移植到CMake，而不影响以前/现在的配置和构建机制。对于一个重要项目的迁移，CMake文件可以与其他构建框架共存，从而允许一个渐进的迁移，包括选项、特性和可移植性，并允许开发社区人员适应新的框架。为了允许传统配置和CMake配置共存一段时间，一个典型的策略是收集CMakeLists.txt文件中的所有CMake代码，以及CMake子目录下的所有辅助CMake源文件的示例中，我们不会引入CMake子目录，而是保持辅助文件要求他们接近目标和来源，但会顾及使用的传统Autotools构建修改的所有文件，但有一个例外：我们将一些修改自动生成文件构建目录下，而不是在源代码树中。

  1. $ ./configure --enable-gui=no
  3. ... lot of output ...
  5. $ make > build.log

我们的示例中(这里没有显示build.log的内容)，我们能够验证编译了哪些源文件以及使用了哪些编译标志(-I. -Iproto -DHAVE_CONFIG_H -g -O2 -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1)。日志文件中，我们可以做如下推断:

  • 所有对象文件都链接到二进制文件中
  • 不生成库
  • 可执行目标与下列库进行连接:-lSM -lICE -lXpm -lXt -lX11 -lXdmcp -lSM -lICE -lm -ltinfo -lelf -lnsl -lacl -lattr -lgpm -ldl

通过在使用message对工程进行调试时，选择添加选项、目标、源和依赖项，我们将逐步实现一个可工作的构建。

获取传统构建的记录

向配置添加任何目标之前，通常有必要看看传统构建的行为，并将配置和构建步骤的输出保存到日志文件中。对于我们的Vim示例，可以使用以下方法实现:

  1. $ ./configure --enable-gui=no
  3. ... lot of output ...
  5. $ make > build.log

示例中(这里没有显示build.log的完整内容)，我们能够验证编译了哪些源文件以及使用了哪些编译标志(-I.-Iproto -DHAVE_CONFIG_H -g -O2 -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1)。从日志文件中，推断如下:

  • 所有对象文件都链接到一个二进制文件中
  • 没有生成库
  • 可执行目标链接到以下库:-lSM -lXpm -lXt -lX11 -lXdmcp -lSM -lSM - linfo -lelf -lnsl -lacl -lattr -lgpm -ldl

调试迁移项目

当目标和命令逐渐移动到CMake端时，使用message命令打印变量的值就非常有用了:

  1. message(STATUS "for debugging printing the value of ${some_variable}")

在使用消息进行调试时，添加选项、目标、源和依赖项，我们将逐步实现一个可工作的构建。

实现选项

找出传统配置为用户提供的选项(例如，通过./configure --help)。Vim项目提供了一个非常长的选项和标志列表，为了使本章的讨论保持简单，我们只在CMake端实现四个选项:

  1. --disable-netbeans Disable NetBeans integration support.
  2. --disable-channel Disable process communication support.
  3. --enable-terminal Enable terminal emulation support.
  4. --with-features=TYPE tiny, small, normal, big or huge (default: huge)

我们还将忽略任何GUI支持和模拟--enable-gui=no，因为它将使示例复杂化。

我们将在CMakeLists.txt中添加以下选项(有默认值)：

  1. option(ENABLE_NETBEANS "Enable netbeans" ON)
  2. option(ENABLE_CHANNEL "Enable channel" ON)
  3. option(ENABLE_TERMINAL "Enable terminal" ON)

我们可以用cmake -D FEATURES=value定义的变量FEATURES来模拟--with-features标志。如果不进行设置，它默认值为”huge”:

  1. if(NOT FEATURES)
  2.     set(FEATURES "huge" CACHE STRING
  3. "FEATURES chosen by the user at CMake configure time")
  4. endif()

我们为使用者提供了一个值FEATURES:

  1. list(APPEND _available_features "tiny" "small" "normal" "big" "huge")
  2. if(NOT FEATURES IN_LIST _available_features)
  3.     message(FATAL_ERROR "Unknown features: \"${FEATURES}\". Allowed values are: ${_available_features}.")
  4. endif()
  5. set_property(CACHE FEATURES PROPERTY STRINGS ${_available_features})

最后一行set_property(CACHE FEATURES PROPERTY STRINGS ${_available_features})，当使用cmake-gui配置项目，则有有不错的效果，用户可根据选择字段清单，选择已经定义了的FEATURES(参见https://blog.kitware.com/constraining-values-with-comboboxes-in-cmake-cmake-gui/ )。

选项可以放在主CMakeLists.txt中，也可以在查询ENABLE_NETBEANS、ENABLE_CHANNEL、ENABLE_TERMINAL和FEATURES的定义附近。前一种策略的优点是，选项列在一个地方，不需要遍历CMakeLists.txt文件来查找选项的定义。因为我们还没有定义任何目标，所以可以先将选项保存在一个文件中，但是稍后会将选项移到离目标更近的地方，通过本地化作用域，得到可重用的CMake构建块。

从可执行的目标开始，进行本地化

让我们添加一些源码。在Vim示例中，源文件位于src下，为了保持主CMakeLists.txt的可读性和可维持性，我们将创建一个新文件src/CMakeLists.txt，并将其添加到主CMakeLists.txt中，从而可以在自己的目录范围内处理该文件:

  1. add_subdirectory(src)

在src/CMakeLists.txt中，可以定义可执行目标，并列出从build.log中获取所有源码:

  1. add_executable(vim
  2.   arabic.c beval.c buffer.c blowfish.c crypt.c crypt_zip.c dict.c diff.c digraph.c edit.c eval.c evalfunc.c ex_cmds.c ex_cmds2.c ex_docmd.c ex_eval.c ex_getln.c farsi.c fileio.c fold.c getchar.c hardcopy.c hashtab.c if_cscope.c if_xcmdsrv.c list.c mark.c memline.c menu.c misc1.c misc2.c move.c mbyte.c normal.c ops.c option.c os_unix.c auto/pathdef.c popupmnu.c pty.c quickfix.c regexp.c screen.c search.c sha256.c spell.c spellfile.c syntax.c tag.c term.c terminal.c ui.c undo.c userfunc.c window.c libvterm/src/encoding.c libvterm/src/keyboard.c libvterm/src/mouse.c libvterm/src/parser.c libvterm/src/pen.c libvterm/src/screen.c libvterm/src/state.c libvterm/src/unicode.c libvterm/src/vterm.c netbeans.c channel.c charset.c json.c main.c memfile.c message.c version.c
  3.   )

这是一个开始。这种情况下，代码甚至不会配置，因为源列表包含生成的文件。讨论生成文件和链接依赖项之前，我们把这一长列表拆分一下，以限制目标依赖项的范围，并使项目更易于管理。如果我们将它们分组到目标，这将使CMake更容易地找到源文件依赖项，并避免很长的链接行。

对于Vim示例，我们可以进一步了解来自src/Makefile和src/configure.ac的源码文件进行分组。这些文件中，大多数源文件都是必需的。有些源文件是可选的(netbeans.c应该只在ENABLE_NETBEANS打开时构建，而channel.c应该只在ENABLE_CHANNEL打开时构建)。此外，我们可以将所有源代码分组到src/libvterm/下，并使用ENABLE_TERMINAL可选地编译它们。

这样，我们将CMake结构重组，构成如下的树结构：

  1. .
  2. ├── CMakeLists.txt
  3. └── src
  4.     ├── CMakeLists.txt
  5.     └── libvterm
  6.         └── CMakeLists.txt

顶层文件使用add_subdirectory(src)添加src/CMakeLists.txt。src/CMakeLists.txt文件包含三个目标(一个可执行文件和两个库)，每个目标都带有编译定义和包含目录。首先定义可执行文件：

  1. add_executable(vim
  2.   main.c
  3.   )
  5. target_compile_definitions(vim
  6.   PRIVATE
  7.       "HAVE_CONFIG_H"
  8.   )

然后，定义一些需要源码文件的目标:

  1. add_library(basic_sources "")
  3. target_sources(basic_sources
  4.   PRIVATE
  5.     arabic.c beval.c blowfish.c buffer.c charset.c
  6.     crypt.c crypt_zip.c dict.c diff.c digraph.c
  7.     edit.c eval.c evalfunc.c ex_cmds.c ex_cmds2.c
  8.     ex_docmd.c ex_eval.c ex_getln.c farsi.c fileio.c
  9.     fold.c getchar.c hardcopy.c hashtab.c if_cscope.c
  10.     if_xcmdsrv.c json.c list.c main.c mark.c
  11.     memfile.c memline.c menu.c message.c misc1.c
  12.     misc2.c move.c mbyte.c normal.c ops.c
  13.     option.c os_unix.c auto/pathdef.c popupmnu.c pty.c
  14.     quickfix.c regexp.c screen.c search.c sha256.c
  15.     spell.c spellfile.c syntax.c tag.c term.c
  16.     terminal.c ui.c undo.c userfunc.c version.c
  17.     window.c
  18.   )
  20. target_include_directories(basic_sources
  21.   PRIVATE
  22.     ${CMAKE_CURRENT_LIST_DIR}/proto
  23.     ${CMAKE_CURRENT_LIST_DIR}
  24.     ${CMAKE_CURRENT_BINARY_DIR}
  25.   )
  27. target_compile_definitions(basic_sources
  28.   PRIVATE
  29.       "HAVE_CONFIG_H"
  30.   )
  32. target_link_libraries(vim
  33.   PUBLIC
  34.       basic_sources
  35.   )

然后，定义一些可选源码文件的目标:

  1. add_library(extra_sources "")
  3. if(ENABLE_NETBEANS)
  4.   target_sources(extra_sources
  5.     PRIVATE
  6.         netbeans.c
  7.     )
  8. endif()
  10. if(ENABLE_CHANNEL)
  11.   target_sources(extra_sources
  12.     PRIVATE
  13.         channel.c
  14.     )
  15. endif()
  17. target_include_directories(extra_sources
  18.   PUBLIC
  19.     ${CMAKE_CURRENT_LIST_DIR}/proto
  20.     ${CMAKE_CURRENT_BINARY_DIR}
  21.   )
  23. target_compile_definitions(extra_sources
  24.   PRIVATE
  25.       "HAVE_CONFIG_H"
  26.   )
  28. target_link_libraries(vim
  29.   PUBLIC
  30.       extra_sources
  31.   )

使用以下代码，对连接src/libvterm/子目录进行选择:

  1. if(ENABLE_TERMINAL)
  2.   add_subdirectory(libvterm)
  4.   target_link_libraries(vim
  5.     PUBLIC
  6.         libvterm
  7.     )
  8. endif()

对应的src/libvterm/CMakeLists.txt包含以下内容:

  1. add_library(libvterm "")
  3. target_sources(libvterm
  4.   PRIVATE
  5.     src/encoding.c
  6.     src/keyboard.c
  7.     src/mouse.c
  8.     src/parser.c
  9.     src/pen.c
  10.     src/screen.c
  11.     src/state.c
  12.     src/unicode.c
  13.     src/vterm.c
  14.   )
  16. target_include_directories(libvterm
  17.   PUBLIC
  18.       ${CMAKE_CURRENT_LIST_DIR}/include
  19.   )
  21. target_compile_definitions(libvterm
  22.   PRIVATE
  23.     "HAVE_CONFIG_H"
  24.     "INLINE="
  25.     "VSNPRINTF=vim_vsnprintf"
  26.     "IS_COMBINING_FUNCTION=utf_iscomposing_uint"
  27.     "WCWIDTH_FUNCTION=utf_uint2cells"
  28.   )

我们已经从build.log中获取了编译信息。树结构的优点是，目标的定义靠近源的位置。如果我们决定重构代码并重命名或移动目录，描述目标的CMake文件就会随着源文件一起移动。

我们的示例代码还没有配置(除非在成功的Autotools构建之后尝试配置)，现在来试试:

  1. $ mkdir -p build
  2. $ cd build
  3. $ cmake ..
  5. -- The C compiler identification is GNU 8.2.0
  6. -- Check for working C compiler: /usr/bin/cc
  7. -- Check for working C compiler: /usr/bin/cc -- works
  8. -- Detecting C compiler ABI info
  9. -- Detecting C compiler ABI info - done
  10. -- Detecting C compile features
  11. -- Detecting C compile features - done
  12. -- Configuring done
  13. CMake Error at src/CMakeLists.txt:12 (add_library):
  14. Cannot find source file:
  15. auto/pathdef.c
  16. Tried extensions .c .C .c++ .cc .cpp .cxx .cu .m .M .mm .h .hh .h++ .hm
  17. .hpp .hxx .in .txx

这里需要生成auto/pathdef.c(和其他文件)，我们将在下一节中考虑这些文件。