源代码

  1. vec4 czm_windowToEyeCoordinates(vec4 fragmentCoordinate)
  2. {
  3.   // 窗口坐标重建NDC坐标
  4.   float x = 2.0 * (fragmentCoordinate.x - czm_viewport.x) / czm_viewport.z - 1.0;
  5.   float y = 2.0 * (fragmentCoordinate.y - czm_viewport.y) / czm_viewport.w - 1.0;
  6.   float z = (fragmentCoordinate.z - czm_viewportTransformation[3][2]) / czm_viewportTransformation[2][2];
  7.   vec4 q = vec4(x, y, z, 1.0);
  9.   // NDC坐标转裁剪（投影）坐标
  10.   q /= fragmentCoordinate.w;
  12.   // 裁剪（投影）坐标转y（相机）坐标
  13.   if (!(czm_inverseProjection == mat4(0.0))) // IE and Edge sometimes do something weird with != between mat4s
  14.   {
  15.     q = czm_inverseProjection * q;
  16.   }
  17.   else
  18.   {
  19.     float top = czm_frustumPlanes.x;
  20.     float bottom = czm_frustumPlanes.y;
  21.     float left = czm_frustumPlanes.z;
  22.     float right = czm_frustumPlanes.w;
  24.     float near = czm_currentFrustum.x;
  25.     float far = czm_currentFrustum.y;
  27.     q.x = (q.x * (right - left) + left + right) * 0.5;
  28.     q.y = (q.y * (top - bottom) + bottom + top) * 0.5;
  29.     q.z = (q.z * (near - far) - near - far) * 0.5;
  30.     q.w = 1.0;
  31.   }
  33.   return q;
  34. }
  36. vec4 czm_windowToEyeCoordinates(vec2 fragmentCoordinateXY, float depthOrLogDepth)
  37. {
  38.   // See reverseLogDepth.glsl. This is separate to re-use the pow.
  39. #ifdef LOG_DEPTH
  40.   float near = czm_currentFrustum.x;
  41.   float far = czm_currentFrustum.y;
  42.   float log2Depth = depthOrLogDepth * czm_log2FarDepthFromNearPlusOne;
  43.   float depthFromNear = pow(2.0, log2Depth) - 1.0;
  44.   float depthFromCamera = depthFromNear + near;
  45.   vec4 windowCoord = vec4(fragmentCoordinateXY, far * (1.0 - near / depthFromCamera) / (far - near), 1.0);
  46.   vec4 eyeCoordinate = czm_windowToEyeCoordinates(windowCoord);
  47.   eyeCoordinate.w = 1.0 / depthFromCamera; // Better precision
  48.   return eyeCoordinate;
  49. #else
  50.   vec4 windowCoord = vec4(fragmentCoordinateXY, depthOrLogDepth, 1.0);
  51.   vec4 eyeCoordinate = czm_windowToEyeCoordinates(windowCoord);
  52. #endif
  53.   return eyeCoordinate;
  54. }

文档

该函数能将窗口坐标计算至眼坐标（也即相机坐标、观察坐标）。有两个重载。

1. 参数

重载1 ① fragmentCoordinate

参数类型：vec4

片元的窗口坐标。

重载2 ① fragmentCoordinateXY

参数类型：vec2

片元的窗口坐标，二维。

重载2 ② depthOrLogDepth

参数类型：float

（对数）深度值。

2. 返回值

返回值类型：vec4

注意事项

depthTexture 可以是对数深度纹理，也可以是非对数深度纹理。