键入的内存视图

原文： http://docs.cython.org/en/latest/src/userguide/memoryviews.html

类型化的内存视图允许有效访问内存缓冲区，例如 NumPy 阵列的内存缓冲区，而不会产生任何 Python 开销。 Memoryview 类似于当前的 NumPy 阵列缓冲支持（np.ndarray[np.float64_t, ndim=2]），但它们具有更多功能和更清晰的语法。

Memoryview 比旧的 NumPy 阵列缓冲支持更通用，因为它们可以处理更多种类的数据源。例如，它们可以处理 C 数组和 Cython 数组类型（ Cython 数组 ）。

memoryview 可以在任何上下文中使用（函数参数，模块级，cdef 类属性等），并且几乎可以通过 PEP 3118 缓冲区接口从任何暴露可写缓冲区的对象中获取。

快速入门

如果您习惯使用 NumPy，以下示例将使您开始使用 Cython 内存视图。

  1. from cython.view cimport array as cvarray
  2. import numpy as np
  4. # Memoryview on a NumPy array
  5. narr = np.arange(27, dtype=np.dtype("i")).reshape((3, 3, 3))
  6. cdef int [:, :, :] narr_view = narr
  8. # Memoryview on a C array
  9. cdef int carr[3][3][3]
  10. cdef int [:, :, :] carr_view = carr
  12. # Memoryview on a Cython array
  13. cyarr = cvarray(shape=(3, 3, 3), itemsize=sizeof(int), format="i")
  14. cdef int [:, :, :] cyarr_view = cyarr
  16. # Show the sum of all the arrays before altering it
  17. print("NumPy sum of the NumPy array before assignments: %s" % narr.sum())
  19. # We can copy the values from one memoryview into another using a single
  20. # statement, by either indexing with ... or (NumPy-style) with a colon.
  21. carr_view[...] = narr_view
  22. cyarr_view[:] = narr_view
  23. # NumPy-style syntax for assigning a single value to all elements.
  24. narr_view[:, :, :] = 3
  26. # Just to distinguish the arrays
  27. carr_view[0, 0, 0] = 100
  28. cyarr_view[0, 0, 0] = 1000
  30. # Assigning into the memoryview on the NumPy array alters the latter
  31. print("NumPy sum of NumPy array after assignments: %s" % narr.sum())
  33. # A function using a memoryview does not usually need the GIL
  34. cpdef int sum3d(int[:, :, :] arr) nogil:
  35.     cdef size_t i, j, k, I, J, K
  36.     cdef int total = 0
  37.     I = arr.shape[0]
  38.     J = arr.shape[1]
  39.     K = arr.shape[2]
  40.     for i in range(I):
  41.         for j in range(J):
  42.             for k in range(K):
  43.                 total += arr[i, j, k]
  44.     return total
  46. # A function accepting a memoryview knows how to use a NumPy array,
  47. # a C array, a Cython array...
  48. print("Memoryview sum of NumPy array is %s" % sum3d(narr))
  49. print("Memoryview sum of C array is %s" % sum3d(carr))
  50. print("Memoryview sum of Cython array is %s" % sum3d(cyarr))
  51. # ... and of course, a memoryview.
  52. print("Memoryview sum of C memoryview is %s" % sum3d(carr_view))

此代码应提供以下输出：

  1. NumPy sum of the NumPy array before assignments: 351
  2. NumPy sum of NumPy array after assignments: 81
  3. Memoryview sum of NumPy array is 81
  4. Memoryview sum of C array is 451
  5. Memoryview sum of Cython array is 1351
  6. Memoryview sum of C memoryview is 451

使用记忆库视图

语法

内存视图以与 NumPy 类似的方式使用 Python 切片语法。

要在一维 int 缓冲区上创建完整视图：

  1. cdef int[:] view1D = exporting_object

完整的 3D 视图：

  1. cdef int[:,:,:] view3D = exporting_object

它们也可以方便地作为函数参数：

  1. def process_3d_buffer(int[:,:,:] view not None):
  2.     ...

参数的not None声明自动拒绝 None 值作为输入，否则将允许。默认情况下允许 None 的原因是它可以方便地用于返回参数：

  1. import numpy as np
  3. def process_buffer(int[:,:] input_view not None,
  4.                    int[:,:] output_view=None):
  6.    if output_view is None:
  7.        # Creating a default view, e.g.
  8.        output_view = np.empty_like(input_view)
  10.    # process 'input_view' into 'output_view'
  11.    return output_view

Cython 将自动拒绝不兼容的缓冲区，例如将三维缓冲区传递给需要二维缓冲区的函数会产生ValueError。

索引

在 Cython 中，内存视图上的索引访问会自动转换为内存地址。以下代码请求 C int类型的项目和索引的二维内存视图：

  1. cdef int[:,:] buf = exporting_object
  3. print(buf[1,2])

负指数也起作用，从相应维度的末尾开始计算：

  1. print(buf[-1,-2])

以下函数循环遍历 2D 数组的每个维度，并为每个项目添加 1：

  1. import numpy as np
  3. def add_one(int[:,:] buf):
  4.     for x in range(buf.shape[0]):
  5.         for y in range(buf.shape[1]):
  6.             buf[x, y] += 1
  8. # exporting_object must be a Python object
  9. # implementing the buffer interface, e.g. a numpy array.
  10. exporting_object = np.zeros((10, 20), dtype=np.intc)
  12. add_one(exporting_object)

索引和切片可以在有或没有 GIL 的情况下完成。它基本上像 NumPy 一样工作。如果为每个维度指定了索引，您将获得基本类型的元素（例如 <cite>int</cite> ）。否则，您将获得一个新视图。省略号表示您为每个未指定的维度获取连续切片：

  1. import numpy as np
  3. exporting_object = np.arange(0, 15 * 10 * 20, dtype=np.intc).reshape((15, 10, 20))
  5. cdef int[:, :, :] my_view = exporting_object
  7. # These are all equivalent
  8. my_view[10]
  9. my_view[10, :, :]
  10. my_view[10, ...]

复制

内存视图可以复制到位：

  1. import numpy as np
  3. cdef int[:, :, :] to_view, from_view
  4. to_view = np.empty((20, 15, 30), dtype=np.intc)
  5. from_view = np.ones((20, 15, 30), dtype=np.intc)
  7. # copy the elements in from_view to to_view
  8. to_view[...] = from_view
  9. # or
  10. to_view[:] = from_view
  11. # or
  12. to_view[:, :, :] = from_view

也可以使用copy()和copy_fortran()方法复制它们;见 C 和 Fortran 连续拷贝 。

转置

在大多数情况下（见下文），内存视图的转置方式与 NumPy 切片可以转置的方式相同：

  1. import numpy as np
  3. array = np.arange(20, dtype=np.intc).reshape((2, 10))
  5. cdef int[:, ::1] c_contig = array
  6. cdef int[::1, :] f_contig = c_contig.T

这为数据提供了一个新的转置视图。

转置要求存储器视图的所有维度都具有直接存取存储器布局（即，没有通过指针的间接指令）。有关详细信息，请参阅 指定更一般的存储器布局 。

Newaxis

对于 NumPy，可以通过使用None索引数组来引入新轴

  1. cdef double[:] myslice = np.linspace(0, 10, num=50)
  3. # 2D array with shape (1, 50)
  4. myslice[None] # or
  5. myslice[None, :]
  7. # 2D array with shape (50, 1)
  8. myslice[:, None]
  10. # 3D array with shape (1, 10, 1)
  11. myslice[None, 10:-20:2, None]

可以将新的轴索引与所有其他形式的索引和切片混合。另见示例。

只读视图

从 Cython 0.28 开始，memoryview 项类型可以声明为const以支持只读缓冲区作为输入：

  1. import numpy as np
  3. cdef const double[:] myslice   # const item type => read-only view
  5. a = np.linspace(0, 10, num=50)
  6. a.setflags(write=False)
  7. myslice = a

使用带有二进制 Python 字符串的非 const 内存视图会产生运行时错误。您可以使用const内存视图解决此问题：

  1. cdef bint is_y_in(const unsigned char[:] string_view):
  2.     cdef int i
  3.     for i in range(string_view.shape[0]):
  4.         if string_view[i] == b'y':
  5.             return True
  6.     return False
  8. print(is_y_in(b'hello world'))   # False
  9. print(is_y_in(b'hello Cython'))  # True

注意，这不是 要求 输入缓冲区是只读的：

  1. a = np.linspace(0, 10, num=50)
  2. myslice = a   # read-only view of a writable buffer

const视图仍然接受可写缓冲区，但非 const，可写视图不接受只读缓冲区：

  1. cdef double[:] myslice   # a normal read/write memory view
  3. a = np.linspace(0, 10, num=50)
  4. a.setflags(write=False)
  5. myslice = a   # ERROR: requesting writable memory view from read-only buffer!

与旧缓冲支持的比较

您可能更喜欢使用旧视图的内存视图，因为：

  • 语法更清晰
  • Memoryview 通常不需要 GIL（参见 Memoryviews 和 GIL）
  • 记忆视图要快得多

例如，这是上面sum3d函数的旧语法等价物：

  1. cpdef int old_sum3d(object[int, ndim=3, mode='strided'] arr):
  2.     cdef int I, J, K, total = 0
  3.     I = arr.shape[0]
  4.     J = arr.shape[1]
  5.     K = arr.shape[2]
  6.     for i in range(I):
  7.         for j in range(J):
  8.             for k in range(K):
  9.                 total += arr[i, j, k]
  10.     return total

请注意，我们不能像上面sum3d的 memoryview 版本那样使用nogil作为函数的缓冲版本，因为缓冲区对象是 Python 对象。但是，即使我们不将nogil与 memoryview 一起使用，它也要快得多。这是导入两个版本后 IPython 会话的输出：

  1. In [2]: import numpy as np
  3. In [3]: arr = np.zeros((40, 40, 40), dtype=int)
  5. In [4]: timeit -r15 old_sum3d(arr)
  6. 1000 loops, best of 15: 298 us per loop
  8. In [5]: timeit -r15 sum3d(arr)
  9. 1000 loops, best of 15: 219 us per loop

Python 缓冲支持

Cython 内存视图几乎支持导出 Python 新样式缓冲区接口的所有对象。这是 PEP 3118 中描述的缓冲接口。 NumPy 数组支持此接口， Cython 数组 也是如此。 “几乎所有”是因为 Python 缓冲区接口允许数据数组中的 元素 本身成为指针; Cython 的内存视图还不支持这一点。

存储器布局

缓冲区接口允许对象以各种方式识别底层内存。除了数据元素的指针外，Cython 内存视图支持所有 Python 新型缓冲区布局。如果内存必须是外部例程的特定格式或代码优化，则了解或指定内存布局可能很有用。

背景

概念如下：有数据访问和数据打包。数据访问意味着直接（无指针）或间接（指针）。数据打包意味着您的数据在内存中可能是连续的或不连续的，并且可以使用 步幅 来识别连续索引需要为每个维度进行的内存跳转。

NumPy 数组提供了一个良好的跨步直接数据访问模型，因此我们将使用它们来更新 C 和 Fortran 连续数组的概念以及数据步幅。

简要概述 C，Fortran 和跨步存储器布局

最简单的数据布局可能是 C 连续数组。这是 NumPy 和 Cython 数组中的默认布局。 C 连续意味着阵列数据在存储器中是连续的（见下文），并且阵列的第一维中的相邻元素在存储器中是最远的，而最后维中的相邻元素最接近在一起。例如，在 NumPy 中：

  1. In [2]: arr = np.array([['0', '1', '2'], ['3', '4', '5']], dtype='S1')

这里，arr[0, 0]和arr[0, 1]在存储器中相隔一个字节，而arr[0, 0]和arr[1, 0]相距 3 个字节。这引出了我们 步幅 的想法。数组的每个轴都有一个步长，这是从该轴上的一个元素到下一个元素所需的字节数。在上面的例子中，轴 0 和 1 的步幅显然是：

  1. In [3]: arr.strides
  2. Out[4]: (3, 1)

对于 3D C 连续数组：

  1. In [5]: c_contig = np.arange(24, dtype=np.int8).reshape((2,3,4))
  2. In [6] c_contig.strides
  3. Out[6]: (12, 4, 1)

Fortran 连续数组具有相反的内存排序，第一个轴上的元素在内存中最接近：

  1. In [7]: f_contig = np.array(c_contig, order='F')
  2. In [8]: np.all(f_contig == c_contig)
  3. Out[8]: True
  4. In [9]: f_contig.strides
  5. Out[9]: (1, 2, 6)

连续数组是单个连续存储器块包含数组元素的所有数据的数组，因此存储器块长度是数组中元素数量和元素大小（以字节为单位）的乘积。在上面的示例中，内存块长度为 2 3 4 * 1 个字节，其中 1 是 int8 的长度。

数组可以是连续的而不是 C 或 Fortran 顺序：

  1. In [10]: c_contig.transpose((1, 0, 2)).strides
  2. Out[10]: (4, 12, 1)

切片 NumPy 数组很容易使它不连续：

  1. In [11]: sliced = c_contig[:,1,:]
  2. In [12]: sliced.strides
  3. Out[12]: (12, 1)
  4. In [13]: sliced.flags
  5. Out[13]:
  6. C_CONTIGUOUS : False
  7. F_CONTIGUOUS : False
  8. OWNDATA : False
  9. WRITEABLE : True
  10. ALIGNED : True
  11. UPDATEIFCOPY : False

内存视图布局的默认行为

正如您在 中看到的那样，指定更一般的内存布局 ，您可以为内存视图的任何维度指定内存布局。对于未指定布局的任何维度，假定数据访问是直接的，并假设数据打包是跨越的。例如，这将是内存视图的假设，如：

  1. int [:, :, :] my_memoryview = obj

C 和 Fortran 连续的内存视图

您可以使用定义中的::1步骤语法为内存视图指定 C 和 Fortran 连续布局。例如，如果您确定您的内存视图将位于 3D C 连续布局之上，您可以编写：

  1. cdef int[:, :, ::1] c_contiguous = c_contig

其中c_contig可以是 C 连续的 NumPy 数组。第 3 位的::1意味着该第 3 维中的元素将是存储器中的一个元素。如果您知道将拥有 3D Fortran 连续数组：

  1. cdef int[::1, :, :] f_contiguous = f_contig

例如，如果传递非连续缓冲区

  1. # This array is C contiguous
  2. c_contig = np.arange(24).reshape((2,3,4))
  3. cdef int[:, :, ::1] c_contiguous = c_contig
  5. # But this isn't
  6. c_contiguous = np.array(c_contig, order='F')

你会在运行时得到ValueError：

  1. /Users/mb312/dev_trees/minimal-cython/mincy.pyx in init mincy (mincy.c:17267)()
  2.     69
  3.     70 # But this isn't
  4. ---> 71 c_contiguous = np.array(c_contig, order='F')
  5.     72
  6.     73 # Show the sum of all the arrays before altering it
  8. /Users/mb312/dev_trees/minimal-cython/stringsource in View.MemoryView.memoryview_cwrapper (mincy.c:9995)()
  10. /Users/mb312/dev_trees/minimal-cython/stringsource in View.MemoryView.memoryview.__cinit__ (mincy.c:6799)()
  12. ValueError: ndarray is not C-contiguous

因此，切片类型规范中的 <cite>:: 1</cite> 指示数据在哪个维度上是连续的。它只能用于指定完整的 C 或 Fortran 连续性。

C 和 Fortran 连续副本

可以使用.copy()和.copy_fortran()方法使 C 或 Fortran 连续复制：

  1. # This view is C contiguous
  2. cdef int[:, :, ::1] c_contiguous = myview.copy()
  4. # This view is Fortran contiguous
  5. cdef int[::1, :] f_contiguous_slice = myview.copy_fortran()

指定更一般的内存布局

可以使用先前看到的::1切片语法或使用cython.view中的任何常量指定数据布局。如果在任何维度中都没有给出说明符，则假定数据访问是直接的，并假设数据打包是跨步的。如果你不知道维度是直接的还是间接的（因为你可能从某个库得到一个带缓冲接口的对象），那么你可以指定<cite>泛型</cite>标志，在这种情况下它将在运行时确定。

标志如下：

  • 通用 - 跨步，直接或间接
  • 跨步 - 跨步（直接）（这是默认值）
  • 间接 - 跨步和间接的
  • 连续的 - 连续的和直接的
  • indirect_contiguous - 指针列表是连续的

它们可以像这样使用：

  1. from cython cimport view
  3. # direct access in both dimensions, strided in the first dimension, contiguous in the last
  4. cdef int[:, ::view.contiguous] a
  6. # contiguous list of pointers to contiguous lists of ints
  7. cdef int[::view.indirect_contiguous, ::1] b
  9. # direct or indirect in the first dimension, direct in the second dimension
  10. # strided in both dimensions
  11. cdef int[::view.generic, :] c

只有间接维度后面的第一个，最后一个或维度可以指定为连续的：

  1. from cython cimport view
  3. # VALID
  4. cdef int[::view.indirect, ::1, :] a
  5. cdef int[::view.indirect, :, ::1] b
  6. cdef int[::view.indirect_contiguous, ::1, :] c
  1. # INVALID
  2. cdef int[::view.contiguous, ::view.indirect, :] d
  3. cdef int[::1, ::view.indirect, :] e

<cite>连续</cite>标志和 <cite>:: 1</cite> 说明符之间的区别在于前者仅指定一个维度的邻接，而后者指定所有后续（Fortran）或前一个（C）的邻接。 ）尺寸：

  1. cdef int[:, ::1] c_contig = ...
  3. # VALID
  4. cdef int[:, ::view.contiguous] myslice = c_contig[::2]
  6. # INVALID
  7. cdef int[:, ::1] myslice = c_contig[::2]

前一种情况是有效的，因为最后一个维度仍然是连续的，但是第一个维度不再“跟随”最后一个维度（意思是，它已经跨越了，但它不再是 C 或 Fortran 连续），因为它被切成了。

Memoryviews 和 GIL

正如您将从 快速入门 部分中看到的那样，内存视图通常不需要 GIL：

  1. cpdef int sum3d(int[:, :, :] arr) nogil:
  2.     ...

特别是，您不需要 GIL 进行内存视图索引，切片或转置。 Memoryviews 需要 GIL 用于复制方法（ C 和 Fortran 连续拷贝 ），或者当 dtype 是对象并且读取或写入对象元素时。

Memoryview 对象和 Cython 阵列

这些类型化的内存视图可以转换为 Python 内存视图对象（ <cite>cython.view.memoryview</cite> ）。这些 Python 对象可以像原始内存视图一样进行索引，可切片和转换。它们也可以随时转换回 Cython 空间的内存视图。

它们具有以下属性：

  • shape：每个维度的大小，作为元组。
  • strides：沿每个维度跨步，以字节为单位。
  • suboffsets
  • ndim：维数。
  • size：视图中的项目总数（形状的乘积）。
  • itemsize：视图中项目的大小（以字节为单位）。
  • nbytes：等于size乘以itemsize。
  • base

当然还有前面提到的T属性（ Transposing）。这些属性与 NumPy 具有相同的语义。例如，要检索原始对象：

  1. import numpy
  2. cimport numpy as cnp
  4. cdef cnp.int32_t[:] a = numpy.arange(10, dtype=numpy.int32)
  5. a = a[::2]
  7. print(a)
  8. print(numpy.asarray(a))
  9. print(a.base)
  11. # this prints:
  12. #    <MemoryView of 'ndarray' object>
  13. #    [0 2 4 6 8]
  14. #    [0 1 2 3 4 5 6 7 8 9]

请注意，此示例返回从中获取视图的原始对象，并在此期间重新查看视图。

Cython 数组

每当复制 Cython 内存视图时（使用任何<cite>副本</cite>或 <cite>copy_fortran</cite> 方法），您将获得新创建的cython.view.array对象的新内存视图片段。此数组也可以手动使用，并自动分配数据块。稍后可以将其分配给 C 或 Fortran 连续切片（或跨步切片）。它可以像：

  1. from cython cimport view
  3. my_array = view.array(shape=(10, 2), itemsize=sizeof(int), format="i")
  4. cdef int[:, :] my_slice = my_array

它还需要一个可选参数<cite>模式</cite>（’c’或’fortran’）和一个布尔 <cite>allocate_buffer</cite> ，它指示缓冲区是否应该在超出范围时分配和释放：

  1. cdef view.array my_array = view.array(..., mode="fortran", allocate_buffer=False)
  2. my_array.data = <char *> my_data_pointer
  4. # define a function that can deallocate the data (if needed)
  5. my_array.callback_free_data = free

您还可以将指针转换为数组，或将 C 数组转换为数组：

  1. cdef view.array my_array = <int[:10, :2]> my_data_pointer
  2. cdef view.array my_array = <int[:, :]> my_c_array

当然，您也可以立即将 cython.view.array 分配给类型化的 memoryview 切片。可以将 C 数组直接分配给 memoryview 切片：

  1. cdef int[:, ::1] myslice = my_2d_c_array

这些数组可以像 Python 内存对象一样从 Python 空间进行索引和切片，并且具有与 memoryview 对象相同的属性。

Python 数组模块

cython.view.array的替代方案是 Python 标准库中的array模块。在 Python 3 中，array.array类型本身支持缓冲区接口，因此内存视图无需额外设置即可在其上工作。

但是，从 Cython 0.17 开始，可以在 Python 2 中使用这些数组作为缓冲提供程序。这是通过显式 cimporting cpython.array模块完成的，如下所示：

  1. cimport cpython.array
  3. def sum_array(int[:] view):
  4.     """
  5.  >>> from array import array
  6.  >>> sum_array( array('i', [1,2,3]) )
  7.  6
  8.  """
  9.     cdef int total
  10.     for i in range(view.shape[0]):
  11.         total += view[i]
  12.     return total

请注意，cimport 还为数组类型启用旧的缓冲区语法。因此，以下也有效：

  1. from cpython cimport array
  3. def sum_array(array.array[int] arr):  # using old buffer syntax
  4.     ...

强制到 NumPy

Memoryview（和数组）对象可以强制转换为 NumPy ndarray，而无需复制数据。你可以，例如做：

  1. cimport numpy as np
  2. import numpy as np
  4. numpy_array = np.asarray(<np.int32_t[:10, :10]> my_pointer)

当然，您不限于使用 NumPy 的类型（例如此处的np.int32_t），您可以使用任何可用的类型。

无切片

尽管 memoryview 切片不是对象，但它们可以设置为 None，并且可以检查它们是否为 None：

  1. def func(double[:] myarray = None):
  2.     print(myarray is None)

如果函数需要实内存视图作为输入，则最好在签名中直接拒绝 None 输入，这在 Cython 0.17 及更高版本中受支持，如下所示：

  1. def func(double[:] myarray not None):
  2.     ...

与扩展类的对象属性不同，memoryview 切片不会初始化为 None。

通过指针从 C 函数传递数据

由于在 C 中使用指针是无处不在的，这里我们给出一个快速示例，说明如何调用其参数包含指针的 C 函数。假设您想要使用 NumPy 管理数组（分配和释放）（它也可以是 Python 数组，或者任何支持缓冲区接口的数组），但是您希望使用C_func_file.c中实现的外部 C 函数对此数组执行计算]：

| 

  1. 1
  2. 2
  3. 3
  4. 4
  5. 5
  6. 6
  7. 7
  8. 8
  9. 9

| 

  1. #include "C_func_file.h"
  3. void multiply_by_10_in_C(double arr[], unsigned int n)
  4. {
  5.     unsigned int i;
  6.     for (i = 0; i &lt; n; i++) {
  7.         arr[i] *= 10;
  8.     }
  9. }

|

此文件附带一个名为C_func_file.h的头文件，其中包含：

| 

  1. 1
  2. 2
  3. 3
  4. 4
  5. 5
  6. 6

| 

  1. #ifndef C_FUNC_FILE_H
  2. #define C_FUNC_FILE_H
  4. void multiply_by_10_in_C(double arr[], unsigned int n);
  6. #endif

|

其中arr指向数组，n是其大小。

您可以通过以下方式在 Cython 文件中调用该函数：

| 

  1.  1
  2.  2
  3.  3
  4.  4
  5.  5
  6.  6
  7.  7
  8.  8
  9.  9
  10. 10
  11. 11
  12. 12
  13. 13
  14. 14
  15. 15
  16. 16
  17. 17
  18. 18
  19. 19
  20. 20
  21. 21
  22. 22
  23. 23
  24. 24
  25. 25
  26. 26
  27. 27
  28. 28

| 

  1. cdef extern from "C_func_file.c":
  2.     # C is include here so that it doesn't need to be compiled externally
  3.     pass
  5. cdef extern from "C_func_file.h":
  6.     void multiply_by_10_in_C(double *, unsigned int)
  8. import numpy as np
  10. def multiply_by_10(arr): # 'arr' is a one-dimensional numpy array
  12.     if not arr.flags['C_CONTIGUOUS']:
  13.         arr = np.ascontiguousarray(arr) # Makes a contiguous copy of the numpy array.
  15.     cdef double[::1] arr_memview = arr
  17.     multiply_by_10_in_C(&arr_memview[0], arr_memview.shape[0])
  19.     return arr
  21. a = np.ones(5, dtype=np.double)
  22. print(multiply_by_10(a))
  24. b = np.ones(10, dtype=np.double)
  25. b = b[::2]  # b is not contiguous.
  27. print(multiply_by_10(b))  # but our function still works as expected.

|

Several things to note:

  • ::1请求 C 连续视图，如果缓冲区不是 C 连续则失败。参见 C 和 Fortran 连续记忆视图 。
  • &arr_memview[0]可以理解为’存储器视图的第一个元素的地址’。对于连续数组，这相当于平坦内存缓冲区的起始地址。
  • arr_memview.shape[0]可能被arr_memview.size，arr.shape[0]或arr.size取代。但arr_memview.shape[0]更有效，因为它不需要任何 Python 交互。
  • 如果传递的数组是连续的，multiply_by_10将就地执行计算，如果arr不连续，它将返回一个新的 numpy 数组。
  • 如果您使用的是 Python 数组而不是 numpy 数组，则无需检查数据是否连续存储，因为总是如此。参见 使用 Python 数组 。

这样，您可以调用类似于普通 Python 函数的 C 函数，并将所有内存管理和清理留给 NumPy 数组和 Python 的对象处理。有关如何在 C 文件中编译和调用函数的详细信息，请参阅 使用 C 库 。