二、流水线核心语法 - 2.3、Jenkins共享库应用 - 《Jenkins》

2.3.1、概述
2.3.2、共享库内容
2.3.3、创建共享库
">
2.3.4、使用共享库
2.3.5、jenkinsfile模板
2.3.6、使用github存jenkinsfile

2.3.1、概述

共享库这并不是一个全新的概念，其实具有编程能力的同学应该清楚一些。例如在编程语言Python中，我们可以将Python代码写到一个文件中，当代码数量增加，我们可以将代码打包成模块然后再以import的方式使用此模块中的方法。

在Jenkins中使用Groovy语法，共享库中存储的每个文件都是一个groovy的类，每个文件（类）中包含一个或多个方法。每个方法包含groovy语句块。

我把共享库代码上传到了github，大家可以参考demo共享库

2.3.2、共享库内容

这是一个demo演示的共享库，大家可以看到仓库的结构与内容。这个仓库中包含了很多类，例如：我将kubernetes中的API方法封装在了kubernetes.groovy文件中，便于后面引用。在此你只需要知道共享库的结构，具体该如何创建共享库后面会讲述**😀**

── docs
│   └── README.mdREADME.md
├── src
│   └── org
│       └── devops
│           └── tools.groovy
└── vars

src目录主要存放我们要编写的groovy类，执行流水线时，此目录将添加到class_path中。 vars目录主要存放脚本文件，这些脚本文件在流水线中作为变量公开。 resources目录允许从外部库中使用步骤来加载相关联的非Groovy文件。

2.3.3、创建共享库

新建文件src/org/devops/tools.groovy, 在此我将这个文件定义为扩展工具类，主要放一些扩展方法。

例如：在构建日志中查看流水线详细日志会很乱，我们可以在日志中将重点步骤通过不同的颜色高亮显示，便于排错。我们开始写这样的一个方法PrintMes(),包含两个参数，输出内容value和内容的颜色color。

注意：我们需要安装插件AnsiColor，这样才能使用ansiColor()方法，可以在片段生成器查看更多的用法。

package org.devops
//格式化输出
def PrintMes(value,color){
    colors = ['red'   : "\033[40;31m >>>>>>>>>>>${value}<<<<<<<<<<< \033[0m",
              'blue'  : "\033[47;34m ${value} \033[0m",
              'green' : "[1;32m>>>>>>>>>>${value}>>>>>>>>>>[m",
              'green1' : "\033[40;32m >>>>>>>>>>>${value}<<<<<<<<<<< \033[0m" ]
    ansiColor('xterm') {
        println(colors[color])
    }
}

创建文件Jenkinslib/vars/hello.groovy。

def call(){
    println("hello")
}

2.3、Jenkins共享库应用 - 图3

2.3.4、使用共享库

我们导航到系统配置 -> Global Pipeline Libraries

首先，我们为共享库设置一个名称jenkinslib，注意这个名称后续在Jenkinsfile中引用。再设置一个默认的版本，这里的版本是分支的名称。我默认配置的是master版本。

接下来我们配置共享库的仓库地址，我的仓库在github中，所以这里我填写的是github的方式。（如果你用的是gitlab可以使用gitlab方式或者git方式）。如果仓库是私有的方式，需要在jenkins的凭据中添加一个账号用于下载共享库。

2.3、Jenkins共享库应用 - 图4

好，到此共享库在Jenkins的配置就完成了，接下来测试在Jenkinsfile中引用。

在Jenkinsfile中使用@Library('jenkinslib') _来加载共享库，注意后面符号_用于加载。类的实例化def tools = new org.devops.tools(),使用类中的方法tools.PrintMes("获取代码",'green')。

这里使用def tools = new org.devops.tools() 会出现命名冲突问题，需要改成其他名称。

#!groovy
@Library('jenkinslib') _     
def mytools = new org.devops.tools()
pipeline {
    agent { node {  label "master" }}
    stages {
        //下载代码
        stage("GetCode"){ 
            steps{  
                timeout(time:5, unit:"MINUTES"){   
                    script{ 
                        mytools.PrintMes("获取代码",'green')
                    }
                }
            }
        }
    }
}

接下来在你的Jenkins上面运行一下吧，测试一下是否能够看到带有绿色的文字呢？

2.3.5、jenkinsfile模板

#!groovy
//引用Library库
@Library('jenkinslib') _  
def mytools = new org.devops.tools()
String workspace = "/opt/jenkins/workspace"
//Pipline
pipeline {
    agent {
        node {
            label "master" //指定运行节点的标签或者名称
            customWorkspace "${workspace}"
        }
    }
    //string 字符串类型的参数, 例如:
    parameters { 
        string(name: 'DEPLOY_ENV', defaultValue: 'staging', description: '') 
    }
    triggers {
        cron('H */4 * * 1-5')
    }
    options {
        timestamps() //日志会有时间
        skipDefaultCheckout() //删除隐藏checkout scm语句
        disableConcurrentBuilds() //禁止并行
        timeout(time: 1, unit: 'HOURS') //流水线超时设置1h
    }
    stages {
        //下载代码
        stage("GetCode"){//阶段名称
            when {
                environment name: 'test', value: 'abcd'  //当test值=abcd时，执行下面step操作
            }
            input {
                message "Should we continue?"
                ok "Yes, we should."
                submitter "alice,bob"
                parameters {
                    string(name: 'PERSON', defaultValue: 'Mr Jenkins', description: 'Who should I say hello to?')
                }
            }
            steps{//步骤
                timeout(time:5, unit: "MINUTES"){//步骤超时时间
                    script{//填写运动代码
                        println('获取代码')
                        println("${test}")
                        echo "Hello ${params.DEPLOY_ENV}"
                        mvnHome = tool "m2"
                        javaHome = tool "jdk"
                        println(mvnHome)
                        sh "${mvnHome}/bin/mvn --version"
                        echo "Hello, ${PERSON}, nice to meet you."
                        mytools.PrintMes("获取代码",'green1')//引用Library库方法
                    }
                }
            }
        }
        //构建
        stage("Build"){//阶段名称
            steps{//步骤
                timeout(time:20, unit: "MINUTES"){//步骤超时时间
                    script{//填写运动代码
                        println('应用打包')
                    }
                }
            }
        }
        //并行构建
        stage("Buildmerge"){//阶段名称
            failFast true // 当其中一个进程失败时，强制所有的 parallel 阶段都被终止
            parallel {
                stage("Build01"){//阶段名称
                    steps{//步骤
                        timeout(time:20, unit: "MINUTES"){//步骤超时时间
                            script{//填写运动代码
                                println('应用打包并行一')
                            }
                        }
                    }
                }
                stage("Build02"){//阶段名称
                    steps{//步骤
                        timeout(time:20, unit: "MINUTES"){//步骤超时时间
                            script{//填写运动代码
                                println('应用打包并行二')
                            }
                        }
                    }
                }
            }
        }            
        //代码扫描
        stage("CodeScan"){//阶段名称
            steps{//步骤
                timeout(time:30, unit: "MINUTES"){//步骤超时时间
                    script{//填写运动代码
                        println('代码扫描')
                    }
                }
            }
        }
    }
    post {
        always {
            script {
                println("always")
            }
        }
        success {
            script {
                currentBuild.description = "\n 构建成功"
            }
        }
        failure {
            script {
                currentBuild.description = "\n 构建失败"
            }
        }
        aborted {
            script {
                currentBuild.description = "\n 构建取消"
            }
        }
    }
}

结果验证

2.3、Jenkins共享库应用 - 图5

2.3.6、使用github存jenkinsfile

2.3、Jenkins共享库应用 - 图6

2.3、Jenkins共享库应用 - 图7