1.   BWS = OWS
    3.    Connection = *( "," OWS ) connection-option *( OWS "," [ OWS connection-option ] )
    5.    Content-Length = 1*DIGIT
    7.    HTTP-message = start-line *( header-field CRLF ) CRLF [ message-body ]
    8.    HTTP-name = %x48.54.54.50 ; HTTP
    9.    HTTP-version = HTTP-name "/" DIGIT "." DIGIT
    10.    Host = uri-host [ ":" port ]
    12.    OWS = *( SP / HTAB )
    14.    RWS = 1*( SP / HTAB )
    16.    TE = [ ( "," / t-codings ) *( OWS "," [ OWS t-codings ] ) ]
    17.    Trailer = *( "," OWS ) field-name *( OWS "," [ OWS field-name ] )
    18.    Transfer-Encoding = *( "," OWS ) transfer-coding *( OWS "," [ OWS transfer-coding ] )
    20.    URI-reference = <URI-reference, see [RFC3986], Section 4.1>
    21.    Upgrade = *( "," OWS ) protocol *( OWS "," [ OWS protocol ] )
    23.    Via = *( "," OWS ) ( received-protocol RWS received-by [ RWS comment ] ) *( OWS "," [ OWS ( received-protocol RWS received-by [ RWS comment ] ) ] )
    25.    absolute-URI = <absolute-URI, see [RFC3986], Section 4.3>
    26.    absolute-form = absolute-URI
    27.    absolute-path = 1*( "/" segment )
    28.    asterisk-form = "*"
    29.    authority = <authority, see [RFC3986], Section 3.2>
    30.    authority-form = authority
    32.    chunk = chunk-size [ chunk-ext ] CRLF chunk-data CRLF
    33.    chunk-data = 1*OCTET
    34.    chunk-ext = *( ";" chunk-ext-name [ "=" chunk-ext-val ] )
    35.    chunk-ext-name = token
    36.    chunk-ext-val = token / quoted-string
    37.    chunk-size = 1*HEXDIG
    38.    chunked-body = *chunk last-chunk trailer-part CRLF
    39.    comment = "(" *( ctext / quoted-pair / comment ) ")"
    40.    connection-option = token
    41.    ctext = HTAB / SP / %x21-27 ; '!'-''' / %x2A-5B ; '*'-'[' / %x5D-7E ; ']'-'~' / obs-text
    43.    field-content = field-vchar [ 1*( SP / HTAB ) field-vchar ]
    44.    field-name = token
    45.    field-value = *( field-content / obs-fold )
    46.    field-vchar = VCHAR / obs-text
    47.    fragment = <fragment, see [RFC3986], Section 3.5>
    49.    header-field = field-name ":" OWS field-value OWS
    50.    http-URI = "http://" authority path-abempty [ "?" query ] [ "#" fragment ]
    51.    https-URI = "https://" authority path-abempty [ "?" query ] [ "#" fragment ]
    53.    last-chunk = 1*"0" [ chunk-ext ] CRLF
    55.    message-body = *OCTET
    56.    method = token
    58.    obs-fold = CRLF 1*( SP / HTAB )
    59.    obs-text = %x80-FF
    60.    origin-form = absolute-path [ "?" query ]
    62.    partial-URI = relative-part [ "?" query ]
    63.    path-abempty = <path-abempty, see [RFC3986], Section 3.3>
    64.    port = <port, see [RFC3986], Section 3.2.3>
    65.    protocol = protocol-name [ "/" protocol-version ]
    66.    protocol-name = token
    67.    protocol-version = token
    68.    pseudonym = token
    70.    qdtext = HTAB / SP / "!" / %x23-5B ; '#'-'[' / %x5D-7E ; ']'-'~' / obs-text
    71.    query = <query, see [RFC3986], Section 3.4>
    72.    quoted-pair = "\" ( HTAB / SP / VCHAR / obs-text )
    73.    quoted-string = DQUOTE *( qdtext / quoted-pair ) DQUOTE
    75.    rank = ( "0" [ "." *3DIGIT ] ) / ( "1" [ "." *3"0" ] )
    76.    reason-phrase = *( HTAB / SP / VCHAR / obs-text )
    77.    received-by = ( uri-host [ ":" port ] ) / pseudonym
    78.    received-protocol = [ protocol-name "/" ] protocol-version
    79.    relative-part = <relative-part, see [RFC3986], Section 4.2>
    80.    request-line = method SP request-target SP HTTP-version CRLF
    81.    request-target = origin-form / absolute-form / authority-form / asterisk-form
    83.    scheme = <scheme, see [RFC3986], Section 3.1>
    84.    segment = <segment, see [RFC3986], Section 3.3>
    85.    start-line = request-line / status-line
    86.    status-code = 3DIGIT
    87.    status-line = HTTP-version SP status-code SP reason-phrase CRLF
    89.    t-codings = "trailers" / ( transfer-coding [ t-ranking ] )
    90.    t-ranking = OWS ";" OWS "q=" rank
    91.    tchar = "!" / "#" / "$" / "%" / "&" / "'" / "*" / "+" / "-" / "." / "^" / "_" / "`" / "|" / "~" / DIGIT / ALPHA
    92.    token = 1*tchar
    93.    trailer-part = *( header-field CRLF )
    94.    transfer-coding = "chunked" / "compress" / "deflate" / "gzip" / transfer-extension
    95.    transfer-extension = token *( OWS ";" OWS transfer-parameter )
    96.    transfer-parameter = token BWS "=" BWS ( token / quoted-string )
    98.    uri-host = <host, see [RFC3986], Section 3.2.2>